Ordenación por Selección Directa

Proceso ordenacion_seleccion
 
     // (c) ciclos-informatica.com
     // Entrada: Vector de enteros
     // Salida: Vector en orden creciente
     // Método de ordenación: Selección Directa
 
     // Línea en blanco
     Escribir ""
 
     // Declaración automática del vector
     n <- azar(9)+2; // Longitud entre 2 y 10
     Dimension v(n)
 
     // Carga automática del vector
     Para i<-1 Hasta n Hacer
             v(i) <- azar(1000)+1; // Valor entre 1 y 1000
     FinPara
 
     // Visualización del vector desordenado
     Escribir "Vector inicial (desordenado):"
     Para i<-1 Hasta n Hacer
	Escribir "     ",v(i)
     FinPara
     Escribir ""
 
     // Ordenación del vector por el método de selección
     Para i<-1 Hasta n-1 Hacer
	posMenor <- i
	Para j<-i+1 Hasta n Hacer
              	     Si v(j)<v(posMenor) Entonces
	             posMenor <-j
	     FinSi
	FinPara
                // Intercambio de v(i) y v(posMenor)
	aux <- v(i)
	v(i) <- v(posMenor)
	v(posMenor) <- aux
     FinPara
 
     // Visualización del vector ordenado
     Escribir "Vector final (ordenado):"
     Para i<-1 Hasta n Hacer
               Escribir "     ",v(i)
     FinPara
     Escribir ""
 
FinProceso

1 Respuesta a “Ordenación por Selección Directa”


  1. 1 gparedes

    Esta muy bien explicado y esctructurado el algoritmo, yo lo uso con una loigera modificación, pero definitivamente la lógica empleada es la misma.

Añade un Comentario